Imports System.Security.Cryptography

Public NotInheritable Class Simple3Des

    Private TripleDes As New TripleDESCryptoServiceProvider
    
    Private Function TruncateHash( 
        ByVal key As String, 
        ByVal length As Integer) As Byte()
    
        Dim sha1 As New SHA1CryptoServiceProvider
    
        ' Hash the key.
        Dim keyBytes() As Byte = 
            System.Text.Encoding.Unicode.GetBytes(key)
        Dim hash() As Byte = sha1.ComputeHash(keyBytes)
    
        ' Truncate or pad the hash.
        ReDim Preserve hash(length - 1)
        Return hash
    End Function
    
    Sub New(ByVal key As String)
        ' Initialize the crypto provider.
        TripleDes.Key = TruncateHash(key, TripleDes.KeySize \ 8)
        TripleDes.IV = TruncateHash("", TripleDes.BlockSize \ 8)
    End Sub
    
    Public Function EncryptData( 
        ByVal plaintext As String) As String
    
        ' Convert the plaintext string to a byte array.
        Dim plaintextBytes() As Byte = 
            System.Text.Encoding.Unicode.GetBytes(plaintext)
    
        ' Create the stream.
        Dim ms As New System.IO.MemoryStream
        ' Create the encoder to write to the stream.
        Dim encStream As New CryptoStream(ms, 
            TripleDes.CreateEncryptor(), 
            System.Security.Cryptography.CryptoStreamMode.Write)
    
        ' Use the crypto stream to write the byte array to the stream.
        encStream.Write(plaintextBytes, 0, plaintextBytes.Length)
        encStream.FlushFinalBlock()
    
        ' Convert the encrypted stream to a printable string.
        Return Convert.ToBase64String(ms.ToArray)
    End Function

	Public Function DecryptData( 
		ByVal encryptedtext As String) As String

		' Convert the encrypted text string to a byte array.
		Dim encryptedBytes() As Byte = Convert.FromBase64String(encryptedtext)

		' Create the stream.
		Dim ms As New System.IO.MemoryStream
		' Create the decoder to write to the stream.
		Dim decStream As New CryptoStream(ms, 
			TripleDes.CreateDecryptor(), 
			System.Security.Cryptography.CryptoStreamMode.Write)

		' Use the crypto stream to write the byte array to the stream.
		decStream.Write(encryptedBytes, 0, encryptedBytes.Length)
		decStream.FlushFinalBlock()

		' Convert the plaintext stream to a string.
		Return System.Text.Encoding.Unicode.GetString(ms.ToArray)
	End Function

End Class

' ------------------------ TEST DU CHIFFREMENT DU CODE

Public Module Program
	Public Sub Main(args() As string)
	  Dim wrapper As New Simple3Des("CLESECRETEPOURCHIFFRER")
	  
	  ' CHIFFREMENT ET ENREGISTREMENT DU CODE
	  Console.WriteLine("CHIFFREMENT ET ENREGISTREMENT DU CODE")
	  
	  ' code est le code généré en fonction du nombre d'utilisation
	  Dim code As String = "CODE"
	  ' writedCryptedCode est le code chiffré qu'on doit mettre dans la base de registre
    Dim writedCryptedCode As String = wrapper.EncryptData(code)
	  
	  Console.WriteLine("Le code est : " & code)
		Console.WriteLine("Dans la base de registre, je mets : " & writedCryptedCode)

		' LECTURE ET DECHIFFREMENT DU CODE
		
		Console.WriteLine("")
		Console.WriteLine("LECTURE ET DECHIFFREMENT DU CODE")
		
	  ' readedCryptedCode est le code chiffré lu dans la base de registre
	  Dim readedCryptedCode As String = "3Avp+12PYQ2W5Mj8TMXoOQ=="

		Console.WriteLine("Dans la base de registre, le lis : " & readedCryptedCode)

    ' on tente de déchiffrer
		Try
        Dim uncryptedCode As String = wrapper.DecryptData(readedCryptedCode)
        Console.WriteLine("Le code à vérifier est : " & uncryptedCode)
    Catch ex As System.Security.Cryptography.CryptographicException
        Console.WriteLine("Le code n'est pas déchiffrage je ne dois pas lancer l'application.")
    End Try

	End Sub
End Module